Interface to SCTP sockets.

This module provides functions for communicating over SCTP sockets. The implementation assumes that the OS kernel supports SCTP (RFC 2960) through the user-level Sockets API Extensions.

During development, this implementation was tested on:

• Linux Fedora Core 5.0 (kernel 2.6.15-2054 or later is needed)
• Solaris 10, 11

During OTP adaptation it was tested on:

• SUSE Linux Enterprise Server 10 (x86_64) kernel 2.6.16.27-0.6-smp, with lksctp-tools-1.0.6
• Briefly on Solaris 10
• SUSE Linux Enterprise Server 10 Service Pack 1 (x86_64) kernel 2.6.16.54-0.2.3-smp with lksctp-tools-1.0.7
• FreeBSD 8.2

This module was written for one-to-many style sockets (type seqpacket). With the addition of peeloff/2, one-to-one style sockets (type stream) were introduced.

Record definitions for this module can be found using:

-include_lib("kernel/include/inet_sctp.hrl").

These record definitions use the "new" spelling 'adaptation', not the deprecated 'adaption', regardless of which spelling the underlying C API uses.

SCTP Socket Options

The set of admissible SCTP socket options is by construction orthogonal to the sets of TCP, UDP, and generic inet options. Here are only options listed that are allowed for SCTP sockets.

Options can be set on the socket when calling open/1,2, and changed when calling connect/4,5 or by calling inet:setopts/2. They can be retrieved using inet:getopts/2.

• {mode, list|binary} | list | binary - Determines the type of data returned from recv/1,2 or in active mode data messages.

• {active, false|true|once|N}

  • If false (passive mode, the default), the caller must do an explicit recv call to retrieve the available data from the socket.

  • If true|once|N (active modes) received data or events are sent to the owning process. See open/0..2 for the message format.

  • If true (fully active mode) there is no flow control.

    Note

    Note that this can cause the message queue to overflow causing for example the virtual machine to run out of memory and crash.

  • If once, only one message is automatically placed in the message queue, and the mode resets to passive. This provides flow control and the possibility for the receiver to listen for incoming SCTP data interleaved with other inter-process messages.

  • If active is specified as an integer N in the range -32768 to 32767 (inclusive), that number is added to the socket's data messages counter. If the result of the addition is negative, the counter is set to 0. Once the counter reaches 0, either through the delivery of messages or by being explicitly set with inet:setopts/2, the socket mode resets to passive ({active, false}). When a socket in {active, N} mode transitions to passive mode, the message {sctp_passive, Socket} is sent to the controlling process to notify that if it wants to receive more data messages from the socket, it must call inet:setopts/2 to set the socket back into an active mode.

• {tos, integer()} - Sets the Type-Of-Service field on the IP datagrams that are sent, to the specified value. This effectively determines a prioritization policy for the outbound packets. The acceptable values are system-dependent.

• {priority, integer()} - A protocol-independent equivalent of tos above. Setting priority implies setting tos as well.

• {dontroute, true|false} - Defaults to false. If true, the kernel does not send packets through any gateway, but only sends them to directly connected hosts.

• {reuseaddr, true|false} - Defaults to false. If true, the local binding address {IP,Port} of the socket can be reused immediately. No waiting in state CLOSE_WAIT is performed (can be required for some types of servers).

• {sndbuf, integer()} - The size, in bytes, of the OS kernel send buffer for this socket. Sending errors would occur for datagrams larger than val(sndbuf). Setting this option also adjusts the size of the driver buffer (see buffer above).

• {recbuf, integer()} - The size, in bytes, of the OS kernel receive buffer for this socket. Sending errors would occur for datagrams larger than val(recbuf). Setting this option also adjusts the size of the driver buffer (see buffer above).

• {sctp_module, module()} - Overrides which callback module is used. Defaults to inet_sctp for IPv4 and inet6_sctp for IPv6.

• {sctp_rtoinfo, #sctp_rtoinfo{}}

  #sctp_rtoinfo{
        assoc_id = assoc_id(),
        initial  = integer(),
        max      = integer(),
        min      = integer()
  }

  Determines retransmission time-out parameters, in milliseconds, for the association(s) specified by assoc_id.

  assoc_id = 0 (default) indicates the whole endpoint. See RFC 2960 and Sockets API Extensions for SCTP for the exact semantics of the field values.

• {sctp_associnfo, #sctp_assocparams{}}

  #sctp_assocparams{
        assoc_id                 = assoc_id(),
        asocmaxrxt               = integer(),
        number_peer_destinations = integer(),
        peer_rwnd                = integer(),
        local_rwnd               = integer(),
        cookie_life              = integer()
  }

  Determines association parameters for the association(s) specified by assoc_id.

  assoc_id = 0 (default) indicates the whole endpoint. See Sockets API Extensions for SCTP for the discussion of their semantics. Rarely used.

• {sctp_initmsg, #sctp_initmsg{}}

  #sctp_initmsg{
       num_ostreams   = integer(),
       max_instreams  = integer(),
       max_attempts   = integer(),
       max_init_timeo = integer()
  }

  Determines the default parameters that this socket tries to negotiate with its peer while establishing an association with it. Is to be set after open/* but before the first connect/*. #sctp_initmsg{} can also be used as ancillary data with the first call of send/* to a new peer (when a new association is created).

  • num_ostreams - Number of outbound streams

  • max_instreams - Maximum number of inbound streams

  • max_attempts - Maximum retransmissions while establishing an association

  • max_init_timeo - Time-out, in milliseconds, for establishing an association

• {sctp_autoclose, integer() >= 0} - Determines the time, in seconds, after which an idle association is automatically closed. 0 means that the association is never automatically closed.

• {sctp_nodelay, true|false} - Turns on|off the Nagle algorithm for merging small packets into larger ones. This improves throughput at the expense of latency.

• {sctp_disable_fragments, true|false} - If true, induces an error on an attempt to send a message larger than the current PMTU size (which would require fragmentation/reassembling). Notice that message fragmentation does not affect the logical atomicity of its delivery; this option is provided for performance reasons only.

• {sctp_i_want_mapped_v4_addr, true|false} - Turns on|off automatic mapping of IPv4 addresses into IPv6 ones (if the socket address family is AF_INET6).

• {sctp_maxseg, integer()} - Determines the maximum chunk size if message fragmentation is used. If 0, the chunk size is limited by the Path MTU only.

• {sctp_primary_addr, #sctp_prim{}}

  #sctp_prim{
        assoc_id = assoc_id(),
        addr     = {IP, Port}
  }
   IP = ip_address()
   Port = port_number()

  For the association specified by assoc_id, {IP,Port} must be one of the peer addresses. This option determines that the specified address is treated by the local SCTP stack as the primary address of the peer.

• {sctp_set_peer_primary_addr, #sctp_setpeerprim{}}

  #sctp_setpeerprim{
        assoc_id = assoc_id(),
        addr     = {IP, Port}
  }
   IP = ip_address()
   Port = port_number()

  When set, informs the peer to use {IP, Port} as the primary address of the local endpoint for the association specified by assoc_id.

• {sctp_adaptation_layer, #sctp_setadaptation{}}

  #sctp_setadaptation{
        adaptation_ind = integer()
  }

  When set, requests that the local endpoint uses the value specified by adaptation_ind as the Adaptation Indication parameter for establishing new associations. For details, see RFC 2960 and Sockets API Extensions for SCTP.

• {sctp_peer_addr_params, #sctp_paddrparams{}}

  #sctp_paddrparams{
        assoc_id   = assoc_id(),
        address    = {IP, Port},
        hbinterval = integer(),
        pathmaxrxt = integer(),
        pathmtu    = integer(),
        sackdelay  = integer(),
        flags      = list()
  }
  IP = ip_address()
  Port = port_number()

  Determines various per-address parameters for the association specified by assoc_id and the peer address address (the SCTP protocol supports multi-homing, so more than one address can correspond to a specified association).

  • hbinterval - Heartbeat interval, in milliseconds

  • pathmaxrxt - Maximum number of retransmissions before this address is considered unreachable (and an alternative address is selected)

  • pathmtu - Fixed Path MTU, if automatic discovery is disabled (see flags below)

  • sackdelay - Delay, in milliseconds, for SAC messages (if the delay is enabled, see flags below)

  • flags - The following flags are available:

    • hb_enable - Enables heartbeat

    • hb_disable - Disables heartbeat

    • hb_demand - Initiates heartbeat immediately

    • pmtud_enable - Enables automatic Path MTU discovery

    • pmtud_disable - Disables automatic Path MTU discovery

    • sackdelay_enable - Enables SAC delay

    • sackdelay_disable - Disables SAC delay

• {sctp_default_send_param, #sctp_sndrcvinfo{}}

  #sctp_sndrcvinfo{
        stream     = integer(),
        ssn        = integer(),
        flags      = list(),
        ppid       = integer(),
        context    = integer(),
        timetolive = integer(),
        tsn        = integer(),
        cumtsn     = integer(),
        assoc_id   = assoc_id()
  }

  #sctp_sndrcvinfo{} is used both in this socket option, and as ancillary data while sending or receiving SCTP messages. When set as an option, it provides default values for subsequent send calls on the association specified by assoc_id.

  assoc_id = 0 (default) indicates the whole endpoint.

  The following fields typically must be specified by the sender:

  • sinfo_stream - Stream number (0-base) within the association to send the messages through;

  • sinfo_flags - The following flags are recognised:

    • unordered - The message is to be sent unordered

    • addr_over - The address specified in send overwrites the primary peer address

    • abort - Aborts the current association without flushing any unsent data

    • eof - Gracefully shuts down the current association, with flushing of unsent data

    Other fields are rarely used. For complete information, see RFC 2960 and Sockets API Extensions for SCTP.

• {sctp_events, #sctp_event_subscribe{}}

  #sctp_event_subscribe{
          data_io_event          = true | false,
          association_event      = true | false,
          address_event          = true | false,
          send_failure_event     = true | false,
          peer_error_event       = true | false,
          shutdown_event         = true | false,
          partial_delivery_event = true | false,
          adaptation_layer_event = true | false
  }

  This option determines which SCTP Events that are to be received (through recv/*) along with the data. The only exception is data_io_event, which enables or disables receiving of #sctp_sndrcvinfo{} ancillary data, not events. By default, all flags except adaptation_layer_event are enabled, although sctp_data_io_event and association_event are used by the driver itself and not exported to the user level.

• {sctp_delayed_ack_time, #sctp_assoc_value{}}

  #sctp_assoc_value{
        assoc_id    = assoc_id(),
        assoc_value = integer()
  }

  Rarely used. Determines the ACK time (specified by assoc_value, in milliseconds) for the specified association or the whole endpoint if assoc_value = 0 (default).

• {sctp_status, #sctp_status{}}

  #sctp_status{
        assoc_id            = assoc_id(),
        state               = atom(),
        rwnd                = integer(),
        unackdata           = integer(),
        penddata            = integer(),
        instrms             = integer(),
        outstrms            = integer(),
        fragmentation_point = integer(),
        primary             = #sctp_paddrinfo{}
  }

  This option is read-only. It determines the status of the SCTP association specified by assoc_id. The following are the possible values of state (the state designations are mostly self-explanatory):

  • sctp_state_empty - Default. Means that no other state is active.

  • sctp_state_closed

  • sctp_state_cookie_wait

  • sctp_state_cookie_echoed

  • sctp_state_established

  • sctp_state_shutdown_pending

  • sctp_state_shutdown_sent

  • sctp_state_shutdown_received

  • sctp_state_shutdown_ack_sent

  Semantics of the other fields:

  • sstat_rwnd - Current receiver window size of the association

  • sstat_unackdata - Number of unacked data chunks

  • sstat_penddata - Number of data chunks pending receipt

  • sstat_instrms - Number of inbound streams

  • sstat_outstrms - Number of outbound streams

  • sstat_fragmentation_point - Message size at which SCTP fragmentation occurs

  • sstat_primary - Information on the current primary peer address (see below for the format of #sctp_paddrinfo{})

• {sctp_get_peer_addr_info, #sctp_paddrinfo{}}

  #sctp_paddrinfo{
        assoc_id  = assoc_id(),
        address   = {IP, Port},
        state     = inactive | active | unconfirmed,
        cwnd      = integer(),
        srtt      = integer(),
        rto       = integer(),
        mtu       = integer()
  }
  IP = ip_address()
  Port = port_number()

  This option is read-only. It determines the parameters specific to the peer address specified by address within the association specified by assoc_id. Field address fmust be set by the caller; all other fields are filled in on return. If assoc_id = 0 (default), the address is automatically translated into the corresponding association ID. This option is rarely used. For the semantics of all fields, see RFC 2960 and Sockets API Extensions for SCTP.

SCTP Examples

Example of an Erlang SCTP server that receives SCTP messages and prints them on the standard output:

-module(sctp_server).

-export([server/0,server/1,server/2]).
-include_lib("kernel/include/inet.hrl").
-include_lib("kernel/include/inet_sctp.hrl").

server() ->
    server(any, 2006).

server([Host,Port]) when is_list(Host), is_list(Port) ->
    {ok, #hostent{h_addr_list = [IP|_]}} = inet:gethostbyname(Host),
    io:format("~w -> ~w~n", [Host, IP]),
    server([IP, list_to_integer(Port)]).

server(IP, Port) when is_tuple(IP) orelse IP == any orelse IP == loopback,
                      is_integer(Port) ->
    {ok,S} = gen_sctp:open(Port, [{recbuf,65536}, {ip,IP}]),
    io:format("Listening on ~w:~w. ~w~n", [IP,Port,S]),
    ok     = gen_sctp:listen(S, true),
    server_loop(S).

server_loop(S) ->
    case gen_sctp:recv(S) of
    {error, Error} ->
        io:format("SCTP RECV ERROR: ~p~n", [Error]);
    Data ->
        io:format("Received: ~p~n", [Data])
    end,
    server_loop(S).

Example of an Erlang SCTP client interacting with the above server. Note that in this example the client creates an association with the server with 5 outbound streams. Therefore, sending of "Test 0" over stream 0 succeeds, but sending of "Test 5" over stream 5 fails. The client then aborts the association, which results in that the corresponding event is received on the server side.

-module(sctp_client).

-export([client/0, client/1, client/2]).
-include_lib("kernel/include/inet.hrl").
-include_lib("kernel/include/inet_sctp.hrl").

client() ->
    client([localhost]).

client([Host]) ->
    client(Host, 2006);

client([Host, Port]) when is_list(Host), is_list(Port) ->
    client(Host,list_to_integer(Port)),
    init:stop().

client(Host, Port) when is_integer(Port) ->
    {ok,S}     = gen_sctp:open(),
    {ok,Assoc} = gen_sctp:connect
        (S, Host, Port, [{sctp_initmsg,#sctp_initmsg{num_ostreams=5}}]),
    io:format("Connection Successful, Assoc=~p~n", [Assoc]),

    io:write(gen_sctp:send(S, Assoc, 0, <<"Test 0">>)),
    io:nl(),
    timer:sleep(10000),
    io:write(gen_sctp:send(S, Assoc, 5, <<"Test 5">>)),
    io:nl(),
    timer:sleep(10000),
    io:write(gen_sctp:abort(S, Assoc)),
    io:nl(),

    timer:sleep(1000),
    gen_sctp:close(S).

A simple Erlang SCTP client that uses the connect_init API:

-module(ex3).

-export([client/4]).
-include_lib("kernel/include/inet.hrl").
-include_lib("kernel/include/inet_sctp.hrl").

client(Peer1, Port1, Peer2, Port2)
  when is_tuple(Peer1), is_integer(Port1), is_tuple(Peer2), is_integer(Port2) ->
    {ok,S}     = gen_sctp:open(),
    SctpInitMsgOpt = {sctp_initmsg,#sctp_initmsg{num_ostreams=5}},
    ActiveOpt = {active, true},
    Opts = [SctpInitMsgOpt, ActiveOpt],
    ok = gen_sctp:connect(S, Peer1, Port1, Opts),
    ok = gen_sctp:connect(S, Peer2, Port2, Opts),
    io:format("Connections initiated~n", []),
    client_loop(S, Peer1, Port1, undefined, Peer2, Port2, undefined).

client_loop(S, Peer1, Port1, AssocId1, Peer2, Port2, AssocId2) ->
    receive
        {sctp, S, Peer1, Port1, {_Anc, SAC}}
          when is_record(SAC, sctp_assoc_change), AssocId1 == undefined ->
            io:format("Association 1 connect result: ~p. AssocId: ~p~n",
                      [SAC#sctp_assoc_change.state,
                       SAC#sctp_assoc_change.assoc_id]),
            client_loop(S, Peer1, Port1, SAC#sctp_assoc_change.assoc_id,
                        Peer2, Port2, AssocId2);

        {sctp, S, Peer2, Port2, {_Anc, SAC}}
          when is_record(SAC, sctp_assoc_change), AssocId2 == undefined ->
            io:format("Association 2 connect result: ~p. AssocId: ~p~n",
                      [SAC#sctp_assoc_change.state, SAC#sctp_assoc_change.assoc_id]),
            client_loop(S, Peer1, Port1, AssocId1, Peer2, Port2,
                       SAC#sctp_assoc_change.assoc_id);

        {sctp, S, Peer1, Port1, Data} ->
            io:format("Association 1: received ~p~n", [Data]),
            client_loop(S, Peer1, Port1, AssocId1,
                        Peer2, Port2, AssocId2);

        {sctp, S, Peer2, Port2, Data} ->
            io:format("Association 2: received ~p~n", [Data]),
            client_loop(S, Peer1, Port1, AssocId1,
                        Peer2, Port2, AssocId2);

        Other ->
            io:format("Other ~p~n", [Other]),
            client_loop(S, Peer1, Port1, AssocId1,
                        Peer2, Port2, AssocId2)

    after 5000 ->
            ok
    end.

See Also

gen_tcp, gen_udp, inet, RFC 2960 (Stream Control Transmission Protocol), Sockets API Extensions for SCTP